Nie chce podawać szczegółów na forum.

 

W kazdym razie chodzi o zrobienie prostego interface`u, dwa suwaki, trzy guziki, na pewno ktos kto w tym siedzi jest w stanie szybko sobie z tym poradzic.

 

Suwaki maja sluzyc do obkrecania obiektu o 360 stopni;

 

guziki np. do otworzenia drzwi 90 stopni i przesuniecia obiektu.

 

Jesli ktos mialby ochote sie z tym pobawic to prosze o kontakt na PM.

 

Dziekuje

proc mainFunction()
{
     if(`window -exists dwaSuwakiTrzyGuziki`){
         deleteUI dwaSuwakiTrzyGuziki;
     }

     string $window = `window dwaSuwakiTrzyGuziki`;



     window -e -widthHeight 490 220 -title "Dwa Suwaki i Trzy Guziki" dwaSuwakiTrzyGuziki;
     columnLayout -adjustableColumn true -columnAlign "left" -columnAttach "left" 10 jakisColumnLayoutA;
                 string $komendaWspolna = "string $obiekt = `optionMenuGrp -q -v objListOptionMenu`;";
                 $komendaWspolna += "float $oTyleX = `floatSliderGrp -q -v obrot_floatSliderGrpX`;";
                 $komendaWspolna += "float $oTyleY = `floatSliderGrp -q -v obrot_floatSliderGrpY`;";
                 $komendaWspolna += "float $mnoznik = `textFieldGrp -q -text mnoznik_txtfieldgrp`;";

                 optionMenuGrp -label "Obracany obiekt" objListOptionMenu;
                     $sceneObjs = `ls -tr`;

                     for($obj in $sceneObjs)
                     {
                        menuItem -label $obj ($obj + "MenuItem");
                     }

                 separator -height 10 -width 480 -style "out" separatorA;

                 textFieldGrp -label "Mnożnik" -editable true -text "1" mnoznik_txtfieldgrp;

                 string $komendaX = $komendaWspolna + "setAttr ($obiekt + \".rotateX\") ($oTyleX*$mnoznik);";
                 floatSliderGrp -label "Obrot X" -field true -min -360 -max 360 -fieldMinValue -360 -fieldMaxValue 360 -changeCommand $komendaX -dragCommand $komendaX obrot_floatSliderGrpX;

                 string $komendaY = $komendaWspolna + "setAttr ($obiekt + \".rotateY\") ($oTyleY*$mnoznik);";
                 floatSliderGrp -label "Obrot Y" -field true -min -360 -max 360 -fieldMinValue -360 -fieldMaxValue 360 -changeCommand $komendaY -dragCommand $komendaY obrot_floatSliderGrpY;

                 separator -height 10 -width 480 -style "out" separatorB;

                 string $komendaO = $komendaWspolna + "setAttr ($obiekt + \".rotateY\") 90;";
                 button -label "Otworz drzwi - czyli ustaw rotY na 90" -align "center" -command $komendaO openButton;

                 string $komendaC = $komendaWspolna + "setAttr ($obiekt + \".rotateY\") 0;";
                 button -label "Zamknij drzwi - czyli ustaw rotY na 0" -align "center" -command $komendaC closeButton;

                 button -label "Wyjdź" -align "center" -command ("deleteUI dwaSuwakiTrzyGuziki;") wyjdzButton;
     setParent..;



     showWindow $window;
}

mainFunction();

Mógłbyś to zagadnienie rozwiązać używając "attrFieldSliderGrp" zamiast spiętych -dragCommand w slider groupach, ale ja wolę mieć większą kontrolę, więc używam zwykłych slider grup.

Edytowane 9 Styczeń 201114 l przez beny